Tema: Separar "elementos".

[xuanprada]

Hola, se pueden separar todos los elementos de un mesh de forma automática?
Es decir, si tengo un personaje mergeado en un solo mesh, se puede decir que se seleccionen todos los "elementos" (o islands) y que los separe en varios meshes?

Supongo que por scripting sea sencillo, pero se puede hacer de forma nativa? Si no, alguien puede guiarme un poquito para el script?

Gracias!

[xuanprada]

Como tenía prisa, he encontrado este script para 3D Max que a hecho el trabajo a la perfección, estaría bien tener lo mismo en Maya y Softiamge.
-----


rollout rolTest "Detach Elems"
(
    button btRun "Detach!" width:90 align:#center offset:[0, -2]

    function detachToNodes oPoly =
    (
        if (classOf oPoly != Editable_Poly) then
            throw "Wrong input in function: detachToNodes()"
       
        local iNumFacesLastElem = 0
        local baElemFaces = #{}
        local sName = ""
   
        while (true) do
        (
            baElemFaces = polyOp.getElementsUsingFace oPoly 1
            sName = uniqueName oPoly.name
            polyOp.detachFaces oPoly baElemFaces delete:true asNode:true name:sName
           
            if ((polyOp.getNumFaces oPoly) == 0) then
            (
                delete oPoly
                exit
            )
   
            if (keyboard.escPressed == true) do
                throw "** escape key pressed **"
        )
    )

    on btRun pressed do
    (
        local currSel = selection as Array
       
        for obj in currSel do
            if ((classOf obj) == Editable_Poly) then
                detachToNodes obj
    )
) -- End Rollout

createDialog rolTest 96 27 style:#(#style_toolwindow, #style_border, #style_sysmenu)

[Cesar Saez]

JP_Separate o DafengIslandSeperation en http://rray.de/xsi

[xuanprada]

Guay! Gracias César.

[animalot]

ARG!!!! Esto lo teníais que haber posteado la semana pasada (((((((